# Maintainer: Hartmut Seichter <hartmut@technotecture.com>

pkgname=zed-sdk-bin
pkgver=4.0.0
pkgdesc="ZED SDK for Stereolabs ZED cameras"
pkgrel=1
arch=('x86_64')
provides=('zed-sdk')

license=('custom:ZED')
depends=('cuda')

url="https://www.stereolabs.com/developers/release/"

makedepends=()

source=(
    "$pkgname-$pkgver.run::https://download.stereolabs.com/zedsdk/4.0/cu121/ubuntu22"
    )

sha256sums=('b65894daa17ceba3b9452e48c43e679eb359f98c049c8b6b5da5c435cbf22e49')

options=(!strip)

install=zed-sdk.install

prepare() {
  # unpack installer
  sh $pkgname-$pkgver.run --target "${srcdir}" --noexec
}

package() 
{
  # make binary folder
  mkdir -p "${pkgdir}/usr/local/zed/bin"
  mkdir -p "${pkgdir}/usr/local/zed/lib"
  mkdir -p "${pkgdir}/usr/local/zed/include"

  mkdir -p "${pkgdir}/usr/share/licenses/${pkgname}"
  mkdir -p "${pkgdir}/usr/lib/"
  mkdir -p "${pkgdir}/usr/lib/cmake/zed-sdk"
  mkdir -p "${pkgdir}/usr/lib/udev/rules.d/"
  
  cp -r "${srcdir}/firmware"     "${pkgdir}/usr/local/zed"
  cp -r "${srcdir}/doc"          "${pkgdir}/usr/local/zed" 
  cp -r "${srcdir}/doc/license/" "${pkgdir}/usr/share/licenses/${pkgname}"
   
  for f in $(find "${srcdir}/tools" -name ZED*); do
    install -Dm755 "$f" "${pkgdir}/usr/local/zed/bin"
  done

  for f in $(find "${srcdir}/lib" -name libsl*); do
    install -Dm644 "$f" "${pkgdir}/usr/local/zed/lib"
  done

  ln -sf "/usr/local/zed/lib/libsl_ai.so"  "${pkgdir}/usr/lib/"
  ln -sf "/usr/local/zed/lib/libsl_zed.so" "${pkgdir}/usr/lib/"

  install -Dm644 "${srcdir}/99-slabs.rules" "${pkgdir}/usr/lib/udev/rules.d/"
  
  install -Dm644 "${srcdir}/zed-config-version.cmake" "${pkgdir}/usr/lib/cmake/zed-sdk/"
  install -Dm644 "${srcdir}/zed-config.cmake"         "${pkgdir}/usr/lib/cmake/zed-sdk/"
  
}