# Maintainer: Hartmut Seichter <hartmut@technotecture.com>

pkgname=zed-sdk-bin
pkgver=3.8.2
pkgdesc="ZED SDK for Stereolabs ZED cameras"
pkgrel=1
arch=('x86_64')
provides=('zed-sdk')

license=('custom:ZED')
depends=('cuda')

url="https://www.stereolabs.com/developers/release/"

makedepends=()

source=(
    "$pkgname-$pkgver.run::https://download.stereolabs.com/zedsdk/3.8/cu117/ubuntu22"
    )

sha256sums=('d537d437603fc0265ffbd76b41ea8046a372ff6d1fa04a076497210bf599a6e6')

options=(!strip)

install=zed-sdk.install

prepare() {
  # unpack installer
  sh $pkgname-$pkgver.run --target "${srcdir}" --noexec
}

package() 
{

  # make binary folder
  mkdir -p "${pkgdir}/opt/zed-sdk/bin"
  mkdir -p "${pkgdir}/opt/zed-sdk/lib"
  mkdir -p "${pkgdir}/opt/zed-sdk/include"

  mkdir -p "${pkgdir}/usr/share/licenses/${pkgname}"
  mkdir -p "${pkgdir}/usr/lib/"
  mkdir -p "${pkgdir}/usr/lib/cmake/zed-sdk"
  mkdir -p "${pkgdir}/usr/lib/udev/rules.d/"

  
  cp -r "${srcdir}/firmware"     "${pkgdir}/opt/zed-sdk"
  cp -r "${srcdir}/doc"          "${pkgdir}/opt/zed-sdk" 
  cp -r "${srcdir}/doc/license/" "${pkgdir}/usr/share/licenses/${pkgname}"
   
  for f in $(find "${srcdir}/tools" -name ZED*); do
    install -Dm755 "$f" "${pkgdir}/opt/zed-sdk/bin"
  done

  for f in $(find "${srcdir}/lib" -name libsl*); do
    install -Dm644 "$f" "${pkgdir}/opt/zed-sdk/lib"
  done

  ln -sf "/opt/zed-sdk/lib/libsl_ai.so"  "${pkgdir}/usr/lib/"
  ln -sf "/opt/zed-sdk/lib/libsl_zed.so" "${pkgdir}/usr/lib/"

  install -Dm644 "${srcdir}/99-slabs.rules" "${pkgdir}/usr/lib/udev/rules.d/"
  
  install -Dm644 "${srcdir}/zed-config-version.cmake" "${pkgdir}/usr/lib/cmake/zed-sdk/"
  install -Dm644 "${srcdir}/zed-config.cmake"         "${pkgdir}/usr/lib/cmake/zed-sdk/"
  
}